《elisp 每日一练》——use-package 的 :ensure、:init、:config 关键字

《elisp 每日一练》——use-package 的 :ensure、:init、:config 关键字

Masimaro
2026-11-22 / 0 评论 / 1 阅读 / 正在检测是否收录...

在前面,我们初步介绍了use-package 包,它是一个专门负责包管理的包。我们利用它可以将包对应的配置组织到一起。我们提到一个简单的use-package 仅仅是对 require 语句进行了错误处理,做到及时require 包报错也不影响Emacs的正常启动。本篇我们来讨论它一些基础关键字的作用和用法

背景知识

就像标题说的,我们今天主要来讨论三个关键。

首先是 :ensure, 就像它的名称一样,用这个关键字来保证包存在。我们来看一个简单的例子

(use-package evil
  :ensure t)

evil 插件的作用简单来说就是在Emacs中模拟vim的操作模式,一般来讲vim用户转到Emacs是离不开它的。我们看看这段代码展开之后的样子:

(progn
  (use-package-ensure-elpa 'evil '(t) 'nil)
  (defvar use-package--warning0
    #'(lambda (keyword err)
        (let
            ((msg
              (format "%s/%s: %s" 'evil keyword
                      (error-message-string err))))
          (display-warning 'use-package msg :error))))
  (condition-case-unless-debug err
      (if (not (require 'evil nil t))
          (display-warning 'use-package
                           (format "Cannot load %s" 'evil) :error))
    (error (funcall use-package--warning0 :catch err))))

对比上一节生成的代码,我们发现它仅仅多了一句 (use-package-ensure-elpa 'evil '(t) 'nil) 。从名称上看,它是use-package 提供的一个内置函数。我们可以找到它的实现代码,因为它的代码比较长,我就不在这里放出来了。但是我们还是需要简单的来看看它的主要流程:

它的函数签名为 use-package-ensure-elpa (name args _state &optional _no-refresh) 这里的args 实际上是通过 :ensure 参数传进去的。

函数的开始就是一个循环 (dolist (ensure args) ...) 它遍历 args 参数,实际上use-package 可以一次安装多个包,而且包名不一定是紧跟在use-package 后面的那个 name 参数的值。

遍历的开始有一段代码:

(let ((package
       (or (and (eq ensure t) (use-package-as-symbol name))
           ensure)))

这里表示如果 ensure 的值是 t 表示name 就是它的包名称。否则直接将 ensure 作为包的描述或者名称。

后面我们看到

(when package
    (require 'package)
    ...)

这里读者请不要犯迷糊了。这里的(require 'package) 和前面获取到的包名并不是一回事。这里实际上在加载Emacs自己的包管理系统 package 包。我们在前面介绍过 package-install 等函数都是来自这个包。

接着我们看到

(when (consp package)
  (use-package-pin-package (car package) (cdr package))
  (setq package (car package)))

这里表明 ensure 实际也可以是 cons cell 的形式,也就是类似于 (evil . "melpa") , 此时 cons cell 的第一个元素将是包的名称。

后面有一行 (unless (package-installed-p package) 表明仅仅在包未被安装的情况下才会执行下面的代码。

后面的安装代码同样被一堆错误处理给包裹了,安装包的核心代码内容为:

(condition-case-unless-debug err
    (progn
      (when (assoc package (bound-and-true-p package-pinned-packages))
        (package-read-all-archive-contents))
      (if (assoc package package-archive-contents)
          (package-install package)
        (package-refresh-contents)
        (when (assoc package (bound-and-true-p package-pinned-packages))
          (package-read-all-archive-contents))
        (package-install package))
      t)
  ...)

这里的核心代码我们可以看到主要流程就是查询 archive-contents 中是否有包信息,如果有则直接下载,否则更新之后在查找下载。

所以分析下来,这个函数实际上就是具有"惰性、归档、安全" 等特性的包下载安装器。

到这里我们也就明白了,:ensure 的实际作用就是调用use-packge 的下载器保证我们想要的包能被正常安装。

有了包之后我们就可以使用包内部提供的函数和功能搭建自己的工作流。我们经常网上的配置在使用 :config 和 :init 它们有什么作用和区别呢

我们利用下面的代码进行展开

(use-package swiper
  :ensure t
  :init
  (global-set-key (kbd "C-s") #'swiper)
  :config
  (setq swiper-include-line-number-in-search t))

看看它们都在什么位置出现

(progn
  (use-package-ensure-elpa 'swiper '(t) 'nil)
  (defvar use-package--warning1
    #'(lambda (keyword err)
        (let
            ((msg
              (format "%s/%s: %s" 'swiper keyword
                      (error-message-string err))))
          (display-warning 'use-package msg :error))))
  (condition-case-unless-debug err
      (progn
        (condition-case-unless-debug err
            (global-set-key (kbd "C-s") #'swiper)
          (error (funcall use-package--warning1 :init err)))
        (if (not (require 'swiper nil t))
            (display-warning 'use-package
                             (format "Cannot load %s" 'swiper) :error)
          (condition-case-unless-debug err
              (progn (setq swiper-include-line-number-in-search t) t)
            (error (funcall use-package--warning1 :config err)))))
    (error (funcall use-package--warning1 :catch err))))

我们发现使用 :init 包裹的代码出现在包加载前,而 :config 的配置出现在包加载之后。但是它们都出现在 package 被下载之后。因此我们可以得出结论,:init 是无论包加载成功与否都会执行,而 :config 在包被require 成功加载之后执行。另外它们都被 condition-case-unless-debug 单独包裹起来了。也就是即使在里面的代码执行报错,也不影响use-package 中其他部分代码的执行。

总结

我们今天介绍了use-package 中常用的3个关键字,总的来说:

  • :ensure 主要用来配置包安装的过程。参数最简单的是传入 t 表示以当前的 name 作为包名,也可以有其他形式
  • :init 在包正式加载之前被执行,所以这里我们应该做一些不依赖包内部函数和功能的操作, 例如提前绑定对应的快捷键
  • :config 在包正式加载之后被执行,这里一般适合对包进行一些配置工作,引用内部的一些函数和功能

另外,它们:init 和 :config 的代码都进行了单独的错误处理,所以它们里面的代码即使出错也不影响后面的代码执行。

0

评论 (0)

取消